What does it do? At the moment it will auto-cast (and recast) Restorative Soil in the direction of your choosing (provided you have the box checked), and when the Elemental 'pops' it will pathfind to that chosen spot. If the Elemental gets within 2 tiles of you you character should (untested) continue pathfinding in the specified direction. Future versions will manage Mirror Images, making it a true SurvivR script.
When you start it, be sure to pick the direction and distance first if you're using the Soil feature, otherwise it will cast at your feet. It is highly recommended that you have 'Always Run' on when using the script.
Post any problems or suggestions you may have, the more feedback I get the better the script will become!
Code: Select all
; BlaZin' Elemental SurvivR
; by BlaZe Budd of Excelsior's ßud ßrothers
; v.7b completed 7/18/09
;;;;; ;;;;; ;;;;; ;;;;; ;;;;;
set %EleTypes HC_DO_NB_YB
set %version .7b
set %dir +++
set %x 0
set %y 0
set #scnt 30
set #lpc 25
;;;;; ;;;;; ;;;;; ;;;;; ;;;;;
gosub showMenu
mainLoop:
if #charGhost = yes
set %soil #false
goSub menuCheck
if %soil && #scnt = 24 && %msg
{
event exMsg #charID 3 33 Soil Recast in 3
set %msg #false
}
if %soil && #scnt > 26
goSub soil
goSub eleCheck
goto mainLoop
;;;;; ;;;;; ;;;;; ;;;;; ;;;;;
sub soil
event macro 1 0 [cs RestorativeSoil
set #lTargetKind 2
set #lTargetX %x
set #lTargetY %y
target 5s
event macro 22
set #scnt 0
set %msg #true
return
;;;;; ;;;;; ;;;;; ;;;;; ;;;;;
sub eleCheck
finditem %EleTypes G_ , 2
if #findKind <> -1
{
event macro 1 0 [e scream
event pathfind %x %y
}
return
;;;;; ;;;;; ;;;;; ;;;;; ;;;;;
sub menuCheck
if #menuButton = closed
halt
menu get Tiles
set %tiles #menuRes
menu get Soil
set %soil #menuRes
if #menuButton <> N/A && #menuButton <> closed
{
set #scnt 23
set %dir #menuButton
set #menuButton N/A
menu Font Align Right
menu Font Size 14
menu Font Style b
menu Font Color Black
menu Font BGColor Purple
menu Delete Direction
menu Text Direction 180 104 %dir
if N in %dir
set %y #charPosY - %tiles
if S in %dir
set %y #charPosY + %tiles
if N notin %dir && S notin %dir
set %y #charPosY
if W in %dir
set %x #charPosX - %tiles
if E in %dir
set %x #charPosX + %tiles
if W notin %dir && E notin %dir
set %x #charPosX
}
return
;;;;; ;;;;; ;;;;; ;;;;; ;;;;;
sub showMenu
menu Clear
menu Window Title Ele SurvivR v %version
menu Window Color Black
menu Window Size 205 140
menu Font Transparent #true
menu Font Align Right
menu Font Name MS Sans Serif
menu Font Size 11
menu Font Style
menu Font Color Green
menu Font Transparent #false
menu Font Align Left
menu Font BGColor Black
menu Text TilesLabel 54 48 Tiles
menu Font Style u
menu Text DirectionLabel 144 82 Direction
menu Font Size 14
menu Font Style b
menu Font Color Black
menu Font BGColor Purple
menu Text Direction 150 104 %dir
menu Font Size 8
menu Font Style
menu Font Color WindowText
menu Button W 6 6 35 35 W
menu Button E 98 98 35 35 E
menu Button SE 52 98 35 35 SE
menu Button S 6 98 35 35 S
menu Button NE 98 52 35 35 NE
menu Button SW 6 52 35 35 SW
menu Button N 98 6 35 35 N
menu Button NW 52 6 35 35 NW
menu Font BGColor Window
menu Combo Create Tiles 50 68 41
menu Combo Add Tiles 1
menu Combo Add Tiles 2
menu Combo Add Tiles 3
menu Combo Add Tiles 4
menu Combo Add Tiles 5
menu Combo Select Tiles 3
menu Font Size 11
menu Font Color Green
menu Font Align Right
menu Font BGColor Black
menu Check Soil 148 8 45 29 #false Soil
menu Show 421 270
set #menuButton N/A
return