Help me tweak this UOSteam Macro please

If you make a Client-side script you can publish it here for other players to use
Post Reply
User avatar
Coalfire
Master Scribe
Posts: 56
Joined: Wed Jan 15, 2020 11:51 pm

Help me tweak this UOSteam Macro please

Post by Coalfire »

Hello fellow UOSteam Macro Gurus. I need help adding a feature to an existing macro, please.

I've tried a few different ways, and it's just not working as desired. If anyone can help, I will be very grateful.


I want to add...
Use Skill: Tracking
Gump Choice: Monster
Gump Choice: First Listing under Monster

I want to work up my Tracking skill while still using this attacker Macro.


Here is the Macro I want to add Tracking too...

Code: Select all

//==================[UOSteam] Alamiester's Easy Fighter V0.3b================//
//============================GRAY Fighting Macro============================//
//===========================Created by Alamiester===========================//
//===========================================================================//
@clearjournal
sysmsg 'Gray Fighting Macro Started' 2400
for 12
  @getenemy! 'murderer' 'enemy' 'criminal' 'gray' 'closest'
  if @findobject! 'enemy'
    //===Primary Ability===//
    if not timerexists 'primaryability'
      settimer 'primaryability' 0
    endif
    if timer 'primaryability' >= 7500 and 'mana' > 32
      @getenemy 'enemy' 'gray' 'criminal' 'murderer' 'nearest'
      @setalias 'enemy1' 'enemy'
      @getenemy 'enemy' 'gray' 'criminal' 'murderer' 'nearest'
      @setalias 'enemy2' 'enemy'
      if serial 'enemy1' != serial 'enemy2'
        if @inrange 'enemy1' 1 or @inrange 'enemy2' 1
          @clearjournal
          setability 'primary' 'on'
        endif
      endif
      settimer 'primaryability' 0'
      pause 300
      if @injournal 'not yet recovered' 'system' or @injournal 'you are already' 'system'
        replay
      endif
    endif
    //===Momentum strike===//
    if not timerexists 'momentumstrike'
      settimer 'momentumstrike' 0
    endif
    if timer 'momentumstrike' >= 1000 and mana > 35
      @getenemy 'enemy' 'gray' 'criminal' 'murderer' 'nearest'
      @setalias 'enemy1' 'enemy'
      @getenemy 'enemy' 'gray' 'criminal' 'murderer' 'nearest'
      @setalias 'enemy2' 'enemy'
      if serial 'enemy1' != serial 'enemy2'
        if @inrange 'enemy1' 1 and @inrange 'enemy2' 1
          @clearjournal
          cast 'Momentum Strike'
          pause 300
          if @injournal 'not yet recovered' 'system' or @injournal 'you are already' 'system'
            replay
          endif
          pause 500
        endif
      endif
    endif
    //===Consecrate Weapon===//
    if not timerexists 'consecrateweapon'
      settimer 'consecrateweapon' 0
    endif
    if timer 'consecrateweapon' >= 9000
      cast "Consecrate Weapon"
      settimer 'consecrateweapon' 0'
      pause 300
      if @injournal 'not yet recovered' 'system' or @injournal 'you are already' 'system'
        replay
      endif
    endif
    if stam < 125
      cast 'Divine Fury'
      pause 300
      if @injournal 'not yet recovered' 'system' or @injournal 'you are already' 'system'
        replay
      endif
    endif
    //===Discord Target===//
    if not timerexists 'discordance'
      settimer 'discordance' 0
    endif
    if timer 'discordance' >= 8000
      useskill "Discordance"
      settimer 'discordance' 0'
      if not targetexists 'any' and inrange 'enemy1' 8 or 'enemy2' 8
        autotargetobject! 'enemy'
      endif
      pause 300
      if @injournal 'You attempt' 'system' or @injournal 'You must' 'system'
        replay
      endif
    endif
    if not targetexists 'any'
      autotargetobject! 'enemy'
    endif
    @attack 'enemy'
  endif
  pause 300
  //if bandaids are less then 50 remove 100 cloth from tailor keys.
  if @counttype '0xe21' 'any' 'backpack' < 50
    @usetype '0x176b' '69' 'backpack' '2'
    pause 300
    waitforgump 1106836505 500
    @replygump 0x41f8fc19 60020
    waitforgump 1106836505 500
    @replygump 0x41f8fc19 0
  endif
  //if cloth found, cut cloth into bandaids
  while @findtype '0x1766' 'any' 'backpack' 'any' '2'
    @usetype '0xf9f' '0' 'backpack' '2'
    pause 300
    @targettype! '0x1766' 'any' '2'
  endwhile
  @clearusequeue
  @cancelautotarget
  @canceltarget
endfor
User avatar
Slartibartfast
Master Scribe
Posts: 50
Joined: Wed Dec 01, 2010 9:35 pm

Re: Help me tweak this UOSteam Macro please

Post by Slartibartfast »

Hello,

In case you haven't already made it work, here's how I'd write it. You can add this where ever you want inside your loop.

Code: Select all

if not timerexists 'trainTracking'
  createtimer 'trainTracking'
  settimer 'trainTracking' 10000
else
  if timer 'trainTracking' >= 10000
    useskill 'Tracking'
    waitforgump 2976808305 15000
    pause 50
    replygump 0xb16e7d71 2
    waitforgump 993494147 15000
    pause 50
    replygump 0x3b378483 1
    pause 50
    settimer 'trainTracking' 0
  endif
endif
The problem you'll face, though, is that you're already using a skill (discordance) in your script, so you'll get that "you must wait to use another skill" message on one skill or the other.

You could try to make the two timers work together with something like...

Code: Select all

if timer 'trainTracking' >= 10000 and timer 'discordance' < 8000
...but that's still going to kill your disco effectiveness. (and I haven't tested that piece to see if it'll even work)
That said, you'll only keep tracking in the script until it's trained up anyway, so you could just put my code at the top of your loop to give it preference over disco and let the two skills fight it out for now. :wink:
In Game: Billy Blacksmith

EasyUO:
Journal Spy | Heal n' Feed

ALT + 42
User avatar
Coalfire
Master Scribe
Posts: 56
Joined: Wed Jan 15, 2020 11:51 pm

Re: Help me tweak this UOSteam Macro please

Post by Coalfire »

I'll give this a try. I'll just replace this with the discord so as to not clash. Once I get Tracking up high enough, I wont need this anymore. This is just to get it high enough to use the tracking feature on the T-Map book.


Thank you Billy
User avatar
Slartibartfast
Master Scribe
Posts: 50
Joined: Wed Dec 01, 2010 9:35 pm

Re: Help me tweak this UOSteam Macro please

Post by Slartibartfast »

You bet. Good luck.
In Game: Billy Blacksmith

EasyUO:
Journal Spy | Heal n' Feed

ALT + 42
Post Reply