You will be prompted to select the loot bag, blade and scissors on first run. You should set macro to loop, macro will automatically stop when no corpses are found. I also recommend setting a hotkey so you have a chance to manually or auto-loot other items first. Don't want to miss those diamonds on the dragons! I normally kill mob, let autoloot agent do it's thing, then Ctrl-H to run this macro.
This macro also uses a list for the cut loot. Leather(all types), wool and hides are included by default. You should be able to add in anything else you want to loot by adding a line like the following in the list creation at top of macro (using the graphic code for the item to loot
Code: Select all
pushlist 'cutloot' '0x9f1' //raw ribs
Code: Select all
//you will be prompted to select loot bag, dagger and scissors on first use
//auto loot may not work on your server !
//also loots feather's and wool (in case you don't like shearing!)
if not listexists 'cutloot'
createlist 'cutloot'
pushlist 'cutloot' '0x1079' //leather
pushlist 'cutloot' '0xdf8' //wool
pushlist 'cutloot' '0x1bd1' //feather
endif
//setup aliases
if not @findobject 'LootBag'
headmsg 'Select a bag to store the loot'
promptalias 'LootBag'
endif
if not @findalias 'blade'
headmsg 'Which blade will you use?'
promptalias 'blade'
endif
if not @findalias 'scissors'
headmsg 'Which scissors do you wish to use?'
promptalias 'scissors'
endif
//look for corpses
if not @findtype '0x2006' 'any' 'ground' '1' '2'
sysmsg ' **** No Corpse Found - Exiting ****' '28'
stop
else
@setalias! 'o' 'found'
endif
//cut corpse
@useobject 'blade'
waitfortarget '1000'
target! 'o'
pause 500
//find loot from loot array
sysmsg ' **** Looking for loot ****' '20'
for 0 to 'cutloot'
while @findtype! cutloot[] 'any' 'o' 'any' '2'
sysmsg ' **** Loot found - Moving ****' '20'
if @injournal 'cannot hold more'
sysmsg ' !!! WARNING: Your bag is full. Exiting script !!!' '28'
clearjournal
stop
else
moveitem 'found' 'LootBag'
pause 1000
endif
endwhile
endfor
//cut hides
while @findtype! '0x1079' 'any' 'LootBag'
sysmsg ' **** Hides found - Cutting ****' '20'
@useobject 'scissors'
waitfortarget '1500'
target! 'found'
pause 500
endwhile
//claim corpse
msg '[claim'
waitfortarget 500
target! 'o'
pause '500'
//cancel claim target
canceltarget